Copy an Issue to a New Project and Link to the Original

    

        
        
        
            
            Expand
                
            
        
    
    import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.config.properties.APKeys
import com.onresolve.scriptrunner.canned.jira.utils.AbstractCloneIssue
import com.onresolve.scriptrunner.canned.jira.utils.CannedScriptUtils
import com.onresolve.scriptrunner.canned.jira.utils.ConditionUtils
import com.onresolve.scriptrunner.canned.jira.workflow.postfunctions.CloneIssue
import com.onresolve.scriptrunner.runner.ScriptRunnerImpl
import groovy.xml.MarkupBuilder

def targetProjectKey = "PROJB"
def issueToCloneKey = "PROJA-1"

def issueToClone = ComponentAccessor.issueManager.getIssueByCurrentKey(issueToCloneKey)
def linkBetweenIssues = CannedScriptUtils.getAllLinkTypesWithInwards(true).find { it.value == "blocks" }?.key?.toString()

// Set the creation parameters/inputs (use clone issue with link type)
def params = [
    (CloneIssue.FIELD_TARGET_PROJECT)       : targetProjectKey,
    (CloneIssue.FIELD_TARGET_ISSUE_TYPE)    : null,
    (CloneIssue.FIELD_COPY_FIELDS)          : AbstractCloneIssue.COPY_ALL_FIELDS,
    (CloneIssue.FIELD_SELECTED_FIELDS)      : null,
    (CloneIssue.FIELD_COPY_COMMENTS)        : false,
    (CloneIssue.FIELD_USER_KEY)             : null,
    (ConditionUtils.FIELD_ADDITIONAL_SCRIPT): ["", ""],
    (CloneIssue.FIELD_LINK_TYPE)            : linkBetweenIssues
] as Map
def executionContext = [issue: issueToClone] as Map

def cloneIssueAction = ScriptRunnerImpl.scriptRunner.createBean(CloneIssue)
// Execute the clone action with the specified params
def updatedExecutionContext = cloneIssueAction.execute(params, executionContext)

// Return the link to the cloned issue
cloneIssueAction ? "Cloned issue: ${createHrefLinkToIssue(updatedExecutionContext.newIssue as String)}" :
    "Could not clone issue, check the logs for errors"

static String createHrefLinkToIssue(String issueKey) {
    def baseUrl = ComponentAccessor.applicationProperties.getString(APKeys.JIRA_BASEURL)
    def writer = new StringWriter()
    def html = new MarkupBuilder(writer)

    html.html {
        a href: "$baseUrl/browse/$issueKey", issueKey
    }

    writer
}